devcon的延伸自动修改IDE控制器和电源管理【源码、原理、程序】

devcon的延伸自动修改IDE控制器和电源管理【源码、原理、程序】

作者：clxp.net.cn 点击：读取中... 次

做封装前总有两个工作要做

1、修改IDE控制器为“标准双通道PCI IDE控制器”
2、修改计算机电源管理为“Standard PC”

现在很多封装工具都有自动实现这两个步骤的功能，但是是如何实现的？到底是做了什么？

很多朋友也有能力做属于自己的封装工具了，但是这两个自动化功能一直比较神秘，没人公开他们的详细的实现原理，有的资料也只是只言片语很模糊，该如何实现这两个功能的自动化？？

怎么自动做这两个工作，笔者也搜寻了好久未果，最终一次偶然的机会得到灵感（其实是做白日梦得到的灵感……- -////），现在把方法和原理告诉大家，让自动化做这两个工作不再神秘，不再成为少数人手里掌握的东西。

希望今天我的努力，可以带来明天大家的成功！

在说如何自动修改这两者之前，要先介绍一个微软的工具，DevCon.exe

立即下载 DevCon 软件包。

引用代码：DevCon，我猜它的意思应该是Device Config（设备设置），不管它是什么意思，这个命令行工具的作用的确很强大，我把它的参数发出来给大家看一下，希望对大家有帮助。

devcon.exe [-r] [-m:\\<machine>] <command> [<arg>...]

-r 如果指定它，在命令完成后若需要则重新启动计算机。
<machine> 是目标计算机的名称。
<command> 是将要执行的命令（如下所示）。
<arg>... 是命令需要的一个或多个参数。
要获取关于某一特定命令的帮助，请键入：devcon.exe help <command>
classfilter   允许修改类别筛选程序。
classes    列出所有设备安装类别。
disable    禁用与指定的硬件或实例 ID 匹配的设备。
driverfiles   列出针对设备安装的驱动程序文件。
drivernodes   列出设备的所有驱动程序节点。
enable    启用与指定的硬件或实例 ID 匹配的设备。
find    查找与指定的硬件或实例 ID 匹配的设备。
findall    查找设备，包括那些未显示的设备。
help    显示此信息。
hwids    列出设备的硬件 ID。
install    手动安装设备。
listclass    列出某一安装类别的所有设备。
reboot    重新启动本地计算机。
remove    删除与特定的硬件或实例 ID 匹配的设备。
rescan    扫描以发现新的硬件。
resources    列出设备的硬件资源。
restart    重新启动与特定的硬件或实例 ID 匹配的设备。
stack    列出预期的设备驱动程序堆栈。
status    列出设备的运行状态。
update    手动更新设备。
UpdateNI    手动更新设备，无用户提示
SetHwID    添加、删除和更改根枚举设备的硬件 ID 的顺序

先来说一下IDE控制器的修改

给这些IDE设备装驱动的时候，会根据windows\inf\mshdc.inf来安装，换句话说，mshdc.inf中记录了系统自带的IDE控制器的驱动相关信息。

这些明白以后，举个例子
现在有IDE控制器A，它的驱动是AD
有IDE控制器B，它的驱动是BD
有标准双通道控制器C，它的驱动是CD
那么有：
A-AD
B-BD
C-CD
这么个对应关系，恰巧，mshdc.inf中也是这样写的。

如果我们直接搜寻A或B设备的驱动，他们会默认安装AD或BD驱动，不会安装CD驱动，因为有明确的对应关系，那么，我们如果能改变这个对应关系，也就是说：
A-CD
B-CD
C-CD
这个时候，如果搜寻A设备的驱动，会安装CD，搜寻B设备的驱动，也会安装CD，由于CD就是标准双通达PCI IDE控制器的驱动，所以无论A、B设备是什么，都会装在CD驱动即“标准双通达PCI IDE控制器”

原理说到这里，那么怎么实现呢？

IDE控制器的相关信息在注册表中：
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}

在这个键下有若干个子键，一般名字为“0000”，“0001”等等，视IDE设备数量而定，不通的硬件配置会有不同。

每个子键下DriverDesc键的值，代表这个设备的名字，就像每个人的名字一样，这个可能会重复。
每个子键下MatchingDeviceId键的值，代表设备的ID，就像每个人的身份证有个身份证号一样，用来唯一标识这个设备。

好的，这样我们要做的是：
1、获取HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}下的每个子键的MatchingDeviceId键值，得到设备ID后看一下同一子键下DriverDesc的键值，看看是不是你当前的IDE控制器，如果是，那么也就是获得了要更改的IDE设备的ID值

2、在windows\inf\mshdc.inf下搜索这个设备的ID值，找到其对应的驱动
例如
我的IDE设备是：PCI\VEN_8086&DEV_7111
而标准双通道IDE设备是：PCI\CC_0101
在windows\inf\mshdc.inf下搜索这两个，发现它们对应的驱动分别是：

%PCI\VEN_8086&DEV_7111.DeviceDesc%=intelide_Inst, PCI\VEN_8086&DEV_7111
%PCI\CC_0101.DeviceDesc% = pciide_Inst,,PCI\CC_0101

这样，我们就把我的IDE设备对应的驱动更换为标准双通道的：
%PCI\VEN_8086&DEV_7111.DeviceDesc%=pciide_Inst,,PCI\CC_0101

3、使用DevCon.exe
（楼上的帖子里已经把这个当作附件传送了上去，请把这个程序放置在windows\system32下，以方便使用）
命令：
devcon update %windir%\inf\mshdc.inf " "PCI\VEN_8086&DEV_7111"
这样系统会搜寻我当前IDE设备的驱动，由于已经把这个驱动替换成了标准双通道的驱动，所以，系统将搜索到“标准双通道PCI IDE控制器”并安装

4、安装完毕后别忘了恢复mshdc.inf到原始的值

基本原理如此，楼下我用AU3自动实现了这一手工过程

AU3程序代码：
用AU3来自动实现更改IDE控制器为标准双通道
（复制在网页上可能会排布有问题，不容易看清，我把源码和程序发在附件里）

每句代码我都带了详细的说明和注释，希望能给大家带来方便。
代码中msgbox(1,"test"开都的部分我已注释掉，这是当时测试留下的信息接口，与程序运行无关。

引用代码：;--------------------------------------------------------------------------------
;本程序用于修改IDE控制器为标准双通道PCI IDE控制器
;适用范围：只用于修改被XP自带驱动识别出来的IDE控制器为“标准双通道PCI IDE控制器”
;
;本程序由自由天空技术论坛开发制作
;自由天空技术论坛：Http://SkyfreeNE.TTsite.Com/
;作者：Skyfree QQ:165718402
;鸣谢本论坛：随缘，小小牧童，紫竹，吉吉，蓝宝
;2007.7.30
;--------------------------------------------------------------------------------

Dim $Class,$Dev,$KeyValue,$i,$j,$Line,$LineNum,$LineNum2,$Line2,$Len,$Str1,$Str2,$FileHandle,$FileHandle2
;主键，该主键下有若干子键
$Class="HKLM\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}\"
;几个计数用的整数
$i=1
$j=1
;文件行号
$LineNum=1
$LineNum2=1
;Windows文件夹下或者Windows\System32文件夹下是否有devcon.exe，若没有则退出程序
If Not (FileExists(@WindowsDir&"\devcon.exe") or FileExists(@WindowsDir&"\system32\devcon.exe")) Then Exit
;Windows\Inf文件夹下是否有mshdc.inf，若有则将mshdc.inf备份为mshdc.inf.bak，否则退出程序
If FileExists(@WindowsDir&"\inf\mshdc.inf") Then
FileMove(@WindowsDir&"\inf\mshdc.inf",@WindowsDir&"\inf\mshdc.inf.bak",1)
Else
Exit
EndIf
;初始条件满足，准备开始更改IDE控制器
While(1)
;读取主键下的子键，
$Dev=RegEnumKey($Class,$i)
;若所有子键读取完毕，则退出程序
If @error=-1 Then
  ExitLoop
EndIf
;读取该子键下MatchingDeviceId的键值，该键值对应着当前IDE控制器，并把此IDE控制器的名称存入$KeyValue中
$KeyValue=RegRead($Class&$Dev,"MatchingDeviceId")
;如果该键值为pci\cc_0101，即IDE控制器已为标准双通道PCI IDE控制器，则无需执行修改，反之则准备开始修改
If $KeyValue<>"pci\cc_0101" Then
  While(1)
    ;以读取模式打开Windows\Inf\mshdc.inf.bak文件
    $FileHandle=FileOpen(@WindowsDir&"\inf\mshdc.inf.bak",0)
    ;读取第$LineNum行，并保存到$Line
    $Line=FileReadLine(@WindowsDir&"\inf\mshdc.inf.bak",$LineNum)
    ;文件若读取完毕则关闭文件并退出循环，文件若未读取完毕则只关闭文件
    If @error=-1 Then
     FileClose($FileHandle)
     ExitLoop
    Else
     FileClose($FileHandle)
    EndIf
    ;$KeyValue中IDE控制器的名称的长度
    $Len=StringLen($KeyValue)
    ;读取$Line中第2到$Len个字符，并保存在$Str1中
    $Str1=StringMid($Line,2,$Len)
    ;MsgBox(1,"test",$Str1&"  "&$KeyValue)
    ;$Line这行中包含$KeyValue中IDE控制器的名称，并在正确的位置上，则开始修改$Line这行的内容
    if $Str1=$KeyValue Then
     ;记录$Line这行中＝所在的位置
     While(1  )
      If StringMid($Line,$j,1)="=" Then
        ;MsgBox(1,"test",StringMid($Line,$j,1))
        ExitLoop
      Else
        ;MsgBox(1,"test",StringMid($Line,$j,1))
        $j=$j+1
      EndIf
     WEnd
     ;Msgbox(1,"test","While done !")
     ;修改这行为$KeyValue中IDE控制器的名称加＝ PCI\CC_0101 的组合
     $Str2=StringMid($Line,1,$j)
     $Str2=$Str2&"pciide_Inst,,PCI\CC_0101"
     ;MsgBox(1,"test",$Str2)
     ;以读取模式打开Windows\Inf\mshdc.inf.bak文件
     $FileHandle=FileOpen(@WindowsDir&"\inf\mshdc.inf.bak",0)
     ;以写入模式打开Windows\Inf\mshdc.inf文件
     $FileHandle2=FileOpen(@WindowsDir&"\inf\mshdc.inf",2)
     ;读取Windows\inf\mshdc.inf.bak，创建Windows\inf\mshdc.inf，用刚修改的那一行替换原有的那一行
     While(1)
      $Line2=FileReadLine(@WindowsDir&"\inf\mshdc.inf.bak",$LineNum2)
      ;MsgBox(1,"test",$LineNum&" "&$LineNum2&" "&$Line2)
      If @error=-1 Then ExitLoop
      If $LineNum2=$LineNum Then
        FileWriteLine(@WindowsDir&"\inf\mshdc.inf",$Str2)
      Else
        FileWriteLine(@WindowsDir&"\inf\mshdc.inf",$Line2)
      EndIf
      $LineNum2=$LineNum2+1
     WEnd
     ;关闭文件
     FileClose($FileHandle)
     FileClose($FileHandle2)
     ;MsgBox(1,"test","mshdc.inf is creat successful")
     ;使用devcon来更新当前IDE控制器，由于当前IDE控制器的驱动以被更改了指向，指向标准双通道PCI IDE控制器的驱动，
     ;所以在更新当前IDE控制器驱动时，会寻找标准双通道PCI IDE控制器的驱动来替代当前的IDE控制器驱动
     ;MsgBox(1,"test","cmd /c devcon update "&@WindowsDir&"\inf\mshdc.inf "&""""&$KeyValue&"""")
     Runwait("cmd /c devcon update "&@WindowsDir&"\inf\mshdc.inf "&""""&$KeyValue&"""","",@SW_HIDE)
     ;变更驱动完毕，退出本次本IDE控制器的驱动变更，继续查找并更改剩余的IDE控制器
     $LineNum=1
     ExitLoop
    EndIf
    $LineNum=$LineNum+1
  WEnd
EndIf
$i=$i+1
WEnd
;所有IDE控制器修改完毕，替换开始备份的原始的mshdc.inf.bak到当前的mshdc.inf
;Windows\Inf文件夹下是否有mshdc.inf.bak，则替换回去，没有则不替换
If FileExists(@WindowsDir&"\inf\mshdc.inf.bak") Then
FileMove(@WindowsDir&"\inf\mshdc.inf.bak",@WindowsDir&"\inf\mshdc.inf",1)
Else
Exit
EndIf

说完了标准双通道PCI IDE控制器的修改，下面来说一说修改Standard PC的方法

这个方法与修改标准双通道PCI IDE控制器的方法不同，相对来说比较简单。

说这个之前，先说点别的，大家应该都装过驱动（废话……），但是想过没有有时候会有好几个驱动适合某设备，但是系统是怎么找到最合适的（起码是系统认为最合适的）并自动安装上的？这里，有个驱动优先级或者说驱动搜寻最优顺序的东西。

系统安装完毕，系统会搜寻一个最适合自己硬件配置的电源管理模式，在所有电源管理模式中，Standard PC的优先级比较低，基本上是不到真的找不到合适的了的时候，系统才启用这种电源管理模式。

所以，我们可以由此想到一些东西，如果能提高Standard PC的优先级，系统会不会自动就搜索到这个？

答案是肯定的，那么我们就来做两件事：
1、修改Standard PC的优先级为最高
2、让系统搜寻驱动并更换计算机电源管理模式到Standard PC

这两件事要怎么做，那就还得请我们的主角程序DevCon.exe来做了

批处理要这样写：
devcon sethwid @ROOT\ACPI_HAL\0000 := +E_ISA_UP !ACPIPIC_UP !ACPIAPIC_UP !ACPIAPIC_MP !MPS_UP !MPS_MP
devcon update %windir%\inf\hal.inf E_ISA_UP

我用AU3实现了这个，楼下提供
（复制在网页上可能会排布有问题，不容易看清，我把源码和程序发在附件里）

每句代码我都带了详细的说明和注释，希望能给大家带来方便。

（不好意思，早上一时疏忽发错了源码，这次的正确了，附件也更新了）

引用代码：;--------------------------------------------------------------------------------
;本程序用于更改计算机电源管理为Standard PC
;
;本程序由自由天空技术论坛开发制作
;自由天空技术论坛：Http://SkyfreeNE.TTsite.Com/
;作者：Skyfree QQ：165718402
;鸣谢本论坛：随缘，小小牧童，紫竹，吉吉，蓝宝
;2007.7.30
;--------------------------------------------------------------------------------

;更改Standard PC需要Windows\Inf\hal.inf文件，若这个文件存在则执行本程序
If FileExists(@WindowsDir&"\inf\hal.inf") Then
;提升Standard PC电源管理的搜寻优先级，降低其他的
Runwait("devcon sethwid @ROOT\ACPI_HAL\0000 := +E_ISA_UP !ACPIPIC_UP !ACPIAPIC_UP !ACPIAPIC_MP !MPS_UP !MPS_MP","",@SW_HIDE)
;搜寻电源管理并更新，由于Standard PC的优先级已被提升，所以这个会首先被搜寻到
Runwait("devcon update "&@windowsdir&"\inf\hal.inf E_ISA_UP","",@SW_HIDE)
EndIf

写在最后

看完这个帖子的朋友可能会有疑问，为什么不能用提高IDE标准双通道的驱动优先级来实现IDE的自动修改？笔者也做过尝试，但是效果不太好，出现了标准双通道和原有的IDE控制器并存的情况，应该是笔者水平有限所致，希望哪个朋友能有更高效的办法解决IDE更改为“标准双通道PCI IDE控制器”的方法！

这两个AU3程序只实现了基本功能，有待提高，希望朋友们能帮助我共同提高这两个程序的适用性。

再次重申，要运行本帖中提供的两个AU3程序，必须先将2楼提供的DevCon.exe下载并复制到Windows下system32文件夹中！

如果我有幸成为了您走向更高层的基石，在您走的更高的时候别忘了告诉我，您是怎么走上去的，呵呵～～～

希望今天我的努力，可以带来明天大家的成功！

转自：http://www.clxp.net.cn/article.asp?id=449

收藏此文章　　　　　打印更新　　　　　编辑此文章　　　　『关闭窗口』


	家园个人文集		http://www.5x54.com