获得用户SID的脚本(vbs)

获得用户SID的脚本(vbs)

作者：网上收集点击：读取中... 次

1.拷贝内容保存为getsid.vbs
2.开始菜单->运行->输入cmd->在命令行窗口中输入cscript [路径]getsid.vbs <用户名>
3.如果不输入用户名，则显示所有的SID。

引用代码：'Getsid v1.0
'seac 13:34 2003-8-3
'------------------------------------------------------------------------------------------------
'
' Usage: Getsid [User Name]
'
' Example 1: Getsid --------Print all sids
' Example 2: Getsid Guest---Print Guest's sid
'
'------------------------------------------------------------------------------------------------

On Error Resume Next

If WScript.Arguments.Count < 1 Then
  ShowSID ""
Else
  ShowSID Trim(WScript.Arguments(0))
End If

Function ShowSID(strUser)
  On Error Resume Next
  Dim oWMI, oAs, oA, sSid
  Set oWMI = GetObject("winmgmts:\\.\root\cimv2")
  If strUser <> "" Then
    Set oAs = oWMI.ExecQuery("Select SID From Win32_Account" & _
         " WHERE SIDType=1 AND Name='" & strUser & "'")
    For Each oA In oAs
      sSid= Mid(oA.SID, InStrRev(oA.SID, "-") + 1)
      WScript.Echo "Short SID: " & sSid & " (" & HEX(sSid) & "H)"
    Next
  Else
    Set oAs = oWMI.ExecQuery("Select Name, SID From Win32_Account WHERE SIDType=1")
    For Each oA In oAs
      WScript.Echo "User: " & oA.Name & _
          vbCrLf & vbTab & "SID: " & oA.SID
    Next
  End If

  Set oA = Nothing
  Set oAs = Nothing
  Set oWMI = Nothing
  If Err.Number <> 0 Then
    WScript.Echo "Error ocurred: " & Err.Description
    Err.Clear
  End If
End Function

收藏此文章　　　　　打印更新　　　　　编辑此文章　　　　『关闭窗口』


	家园个人文集		http://www.5x54.com